一、条件选股编写基本技巧
1、阶段涨跌幅计算：计算当前收盘价相对以前某天收盘价的涨跌幅度。
公式为(CLOSE-REF(CLOSE,N))/REF(CLOSE,N)*100，等同于
，其中函数REF（CLOSE，N）用于计算N天前的收盘价。
2、创新高选股：即当天收盘价为N日来的新高。
HIGH=HHV（HIGH，N），其中函数HHV（HIGH，N）用于计算N天以来的最高价，当N为0时，计算该股历史最高价。‘=’表示这是一个逻辑表达式，成立时此表达式的结果为1，否则为0。
如果要选择近一周内创历史新高的股票，可用HHV（HIGH，5）=HHV（HIGH，0）逻辑表达式。
3、放量上攻：即指价格上涨，成交量剧增。
价格上涨为用公式CLOSE/REF(CLOSE,5)>1.2，等同于逻辑表达式
，指5日内上涨20%；
成交量剧增用逻辑表达式VOL>MA(VOL,5)*3，表示成交量超过近5日均量的3倍；
以上两个条件均要满足，使用AND语句将两个表达式连接起来：
CLOSE/REF(CLOSE,5)>1.2 AND VOL>MA(VOL,5)*3
4、窄幅整理：指一段时间内价格维持在一定范围内。
(HHV(CLOSE,20)-LLV(CLOSE,20))/CLOSE<0.08，其中HHV(CLOSE,20)计算近20日内的最高收盘价，LLV(CLOSE,20)计算近20日内的最低收盘价，0.08表示价格振幅为8%以内。
5、前期高点价格及其位置计算：
第一步，前期高点价格可以写为HHV(HIGH,20)，表示最近20日内的最高价。
第二步，前期高点位置可以写为HHVBARS(HIGH,20)，表示最近20日内最高价到现在的周期数，若HHVBARS(HIGH,20)等于6 则表示前期高点出现在6天前。
函数HHVBARS(X,N)，表示求N周期内X最高值到当前周期数，N=0表示从第一个有效值开始统计，即计算股票的历史最高价。
6、60天前到40天前之间的最高价
函数HHV用于计算以前某天到当天这段时间区间内的最高价。
本问题可以换成另一种表述方式，即计算40天前的20日最高价。所以公式可以写为：
REF(HHV(HIGH,20),40)。函数REF(X,A)，表示向前引用若干周期前的数据。如：REF(CLOSE,1)表示上一周期的收盘价，在日线上就是昨收。
7、求1998年8月1日到1998年12月31日间的最高价
第一步，把这个时间区间内每天的最高价提取出来：
HH:= IF(YEAR=1998 AND MONTH>=8 AND MONTH<=12,HIGH,0)，不在这个区间的最高价则强制设为0。
第二步，将提取出来的每日最高价HH使用函数HHV进行汇总统计，算出最高价：
HHV(HH,0)，其中0表示将所有计算出来的HH都进行统计。
8、动态平均
平滑移动平均是将当日数据X乘以权重a 后，与上一天移动平均数
乘以权重（1-a）相加。公式中指数平滑移动平均函数EMA（X，N）取的权重
，这种设计方式是为避免股票上市首日分母为0时无法计算的问题。因此EMA的完整表达式如下：
移动平均函数SMA(X,N,M)的权重a=M/N，N为天数，M为自设值。
动态移动平均函数DMA（X，A）的权重a=A，这个函数使用起来就更为灵活，如可用换手率作为权重计算均线：DMA(CLOSE,VOL/CAPITAL)。换手率为成交量VOL除以流通盘CAPITAL。
9、线性回归
线性回归是统计学中最常用的方法之一，它用一条直线来近似描述一条曲线。直线可用起点和斜率来表示，因此可以更为简便地概述当前股价的趋势。
线性回归函数有两个：FORCAST和SLOPE，分别表示起点和斜率。
FORCAST的作用与均线类似，有对未来趋势的预测作用，指示较均线更为灵敏。将最近N天的收盘价拟合成一条直线，使得N天来的收盘价距此直线距离的平方和最小（也就是方差最小），那么就可以说这条直线最能代表N天来收盘价的走势，以此预测未来股价。
SLOPE表示该线性回归的斜率，即事件每增加1天价格的变动情况，它可以表示一段时间内的平均价格变化率，可以用它来描述近期价格的涨跌趋势及强度。
FORCAST函数的结果是一条直线，直线的表达式是Y=a+b*X，而SLOPE的计算结果就是这个表达式中的b值。
例如：SLOPE(CLOSE,10)/REF(CLOSE,10)>0.05，表示近期有每日平均5%的升幅趋势。
10、点到面转换
有时我们需要过去发生的事件。例如条件选股最近20日内是否发生涨停等，由于涨停仅在当天可以计算出来，因此需要用点到面转换将该影响延续成一段时间：
TTTT:=CLOSE/REF(CLOSE,1)>1.099 表示涨幅大于10%
COUNT(TTTT,20)>0，该函数统计20 日内涨停的天数，若发生涨停则会对将来30 天产生影响。COUNT、SUM、HHV，LLV 等函数均有点到面转换的作用。
上图分别显示TTTT、HHV(TTTT,20)、COUNT(TTTT,20)三条曲线的相对位置关系，我们看到，每当发生涨停时TTTT 就为1，否则就为0；HHV(TTTT,20)只要20天以内发生过涨停就为1，否则为0，它利用了发生情况时数值最大这一特点将求最大值转化为求指定值；而COUNT(TTTT,20)则表示了20 天之内发生过多少次指定事件，应该说对于本问题这个函数用的最适合。
11、历史某阶段的涨幅
例如要计算20120104-20120629这一时段的涨幅，因为在时间序列轴上无法满足时间的不变性，所以我们需要使用上面所讲的点到面的技巧：
A1：=IF(DATE=1120104,CLOSE,0)；
A2：=SUM(A1,0)，这样我们就可以得到5.19 当日的收盘价，同样得到6.29日的收盘价-
B1：=IF(DATE=1120629,CLOSE,0)；
B2：=SUM(B1,0);
C1：=B2-B1;
然后取得一个涨幅即可。
12、面到点转换
有时我们需要反过来做面到点的转换，例如当RSI 高于80表示股价处于超买阶段，应该卖出。但由于超过80是一个阶段，如果这个阶段中每天都发出卖出信号就不是太好了，需要一个将连续区间转化为一个信号的函数，即面到点的转换：
CROSS(RSI,80)，表示RSI 向上穿越80，由于对于一个阶段来说穿越只会发生一次，从而完成了面到点的转换。
例如，股价突破5日均线买入，跌破5日均线卖出，买入和卖出用箭头表示，代码如下：
A1:CROSS (CLOSE,MA(CLOSE,5));
A2:CROSS(MA(CLOSE,5),CLOSE);
DRAWTEXT(A1,LOW*0.98,‘↑’),COLORRED;
DRAWTEXT(A2,HIGH*1.02,‘↓’),COLOR00FFFF;
13、之字转向
每当股价涨跌幅超过指定界限并发生趋势方向变化时，之字转向会产生一个转向点。将所有转向点用线段连接就成为之字转向。用之字转向能够很好地描述股价的大体走势，对于形态分析有一定的作用。
转向点分为波峰和波谷两类，分别表示向下转向和向上转向，与之对应的四个函数用于描述它们的价格和位置：
PEAK和TROUGH表示波峰和波谷的价格；
PEAKBARS 和TROUGHBARS表示波峰和波谷距现在的周期数；
这四个函数都有一个参数用于描述向前数第几个波峰，利用这个特性就可以在测试W 形底时比较上一个波谷和更前一个波谷的位置和大小，从而规范了一个W形底的描述。
二、K线形态选股
以上K线形态从左到右依次为：阳线、阴线、光头阳线、带帽阳线、带尾阳线、
光头阴线、带尾阴线、带帽阴线、平盘线、十字星、丁字线、倒丁字线。
1、大阳线
首先，编写一个简单的单根K线公式。K线由四个价格组成：开盘价、收盘价、最高价、最低价。因此对它的描述只需清楚的描述这四个价位中的相关性即可。
根据大阳线形态特点：
开盘价既为最低价：BB:=LOW=OPEN；
收盘价既为最高价：AA:=HIGH=CLOSE；
特征“大”的表述可以量化为涨幅，假设涨幅超过7%即认定为“大”：CC:=CLOSE/OPEN>1.07；
三个条件同时满足即表示大阳线：AA AND BB AND CC；
在编写公式的时候，应当将复杂的条件分拆开后形成简单的小语句，最后再组合起来，如：
条件一: AA:=…….
条件二: BB:=…….
…..
…..
汇总： AA AND BB AND ….
2、穿头破脚
穿头破脚，由两根K线组成，表示行情将要转向。第二根K线的柱体部分长于第一根K线且两根K线的颜色相反。若是上升行情第一根K线为阳线，若是下跌行情第一根K线为阴线，并且包含了前一根。
如果只是满足以上基本条件的穿头破脚形态，其信号的含义并不强，所以可以通过强化一些条件或者补充一些条件来加强信号。
例如，规定前一日的涨跌幅大于4%：
A1:=REF(CLOSE,1);
A2:=REF(OPEN,1);
AA:=A1/A2>1.04;
第二根K线形体：
B1:=OPEN<A1;{开盘价低于前一根K线的收盘价}
B2:=CLOSE>A2;{收盘价高于前一根K线的开盘价}
将以上条件组合：
AA AND B1 AND B2;
最终的公式组为:
A1:=REF(CLOSE,1);
A2:=REF(OPEN,1);
AA:=A1/A2>1.04;
B1:=OPEN<A1;
B2:=CLOSE>A2;
AA AND B1 AND B2;
如果是向下的穿头破脚,只需要改动几个数值的方向即可。
3、吊颈
【形态特点】：
a、吊颈出现在上升行情中，表示将见顶回落；
b、有较长的脚部；
c、K线实体部分很少；
d、且在顶部出现；
同样可以有阳线实体的吊颈和阴线实体之分,以下将以阴线实体的吊颈为例。
【量化】：
a、开盘价所得即为当天最高价：AA:=OPEN=HIGH；
b、阴线实体的长度小，量化为其长度小于整个线体的1/3：
B1:=OPEN-CLOSE；
B2:=HIGH-LOW；
BB:=B1/B2<1/3；
c、规定线形的绝对长度，即振幅大于最高价的5%。意义在于加强线体的含义，以免出现弱市中极小的信号：
CC:=B2/HIGH>0.05；
d、公式组合结果如下：
A1:=OPEN=HIGH；
B1:=OPEN-CLOSE；
B2:=HIGH-LOW；
BB:=B1/B2<1/3；
C1:=B2/HIGH>0.05；
AA AND BB AND CC
4、低开大阳线
【形态特点】：
低开大阳线出现在拉升初期或者整理的末期的几率较高。当天的开盘明显低于昨天的K 线, 但是整个线体呈现为一根长阳。
【量化】：
a、开盘价小于前一根K线的最低价：
A1:=REF(CLOSE,1)；
A2:=REF(LOW,1)；
A3:=OPEN<A2；
b、并且开盘价的跌幅达到了2个点以上：
A4:=OPEN/A1<0.98；
c、收盘长阳，收盘价高出开盘价至少8个点以上：
B1:=CLOSE/OPEN>1.08；
d、为强化信息，增加一个放量的辅助条件，要求当日换手率达到5%以上：
C1:=VOL/CAPITAL>0.05；
e、公式组合结果如下：
A1:=REF(CLOSE,1)；
A2:=REF(LOW,1)；
A3:=OPEN<A2；
A4:=OPEN/A1<0.98；
B1:=CLOSE/OPEN>1.08；
C1:=VOL/CAPITAL>0.05；
A3 AND B1 AND C1
5、跳空缺口
【形态特点】：
跳空缺口，指前后相邻两条K线的最高、最低价出现不衔接的情况。是日后支撑或压力点的参考价位。
选股条件：当一个跳空缺口出现时，原有的上涨或下跌走势将加速。
【量化】：
跳空分为向上和向下两种情况，以向上跳空为例。
a、第二根K线的最低价高于第一根K线的最高价：
A1:=REF(HIGH,1)；
A2:=LOW>A1；
b、因为跳空缺口越大，信号越强烈。所以加入辅助条件，即缺口的长度至少有两个点位：
B1:=LOW/A1>1.02；
c、公式组合结果如下：
A1:=REF(HIGH,1)；
A2:=LOW>A1；
B1:=LOW/A1>1.02；
A2 AND B1
6、黄昏之星
【形态特点】：
在一根大阳线后，出现十字星或类似十字星的小阴线，接着出现一根大阴线。这就是“黄昏之星”。表示下跌趋势将逆转。
在一根大阴线后，出现十字星或类似十字星的小阳线，接着出现一根大阳线。这个阳线称为“早晨之星”。表示上升趋势将逆转。
因此，黄昏之星由三条K线组成。以下以黄昏之星为例，早晨之星的表述形式相同、方向相反。
【量化】：
a、第一根K线涨幅为3%，以此描述其为阳线：
A1：=REF(CLOSE,2)/REF(OPEN,2) > 1.03；
b、第二根K线高开：
A2：=REF(OPEN,1) > REF(CLOSE,2)；
c、第二根K线为十字星或小阴线：
A3：=ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.02；
取绝对值函数ABS用来防止出现负数。
d、第三根K线跌幅为3%，以此描述其为阴线：
A4：=CLOSE/OPEN<0.97；
e第三根K线收盘价低于第一根K线的收盘价，以增强趋势逆转的可靠性：
A5：=CLOSE<REF(CLOSE,2)；
e、公式组合结果如下：
A1：=REF(CLOSE,2)/REF(OPEN,2) > 1.03；
A2：=REF(OPEN,1) > REF(CLOSE,2)；
A3：=ABS(REF(OPEN,1)-REF(CLOSE,1))/REF(CLOSE,1)<0.02；
A4：=CLOSE/OPEN<0.97；
A5：=CLOSE<REF(CLOSE,2)；
A1 AND A2 AND A3 AND A4 AND A5；
7、三只乌鸦
三只乌鸦，由三条阴线组成且每日收盘价都下移，表示可能见顶回落。简略公式代码如下:
A1:=REF(CLOSE,1)；
A2:=CLOSE<REF(CLOSE,1)；
COUNT(A2,3)=3
趋势出现反转时产生的此形态，对逃顶最有效。趋势进行过程中的形态已无太大参考意义。可以加入一些辅助的条件优化公式，以得到更加有效的信号。
例如，加入一个判断，两天前的最高价是30天以来的最高价:
AA:=REF(HIGH,2)；
BB:=HHV(HIGH,30)；
AA=BB；
将该条件和前面的描述相结合，可过滤掉许多的虚假信号。
三、技术指标选股
1、MA均线指标选股
【MA(金叉)，普通金叉】：
其定义为：5日均线和10日均线在30日均线上方，5日均线由下向上穿过10日均线。
首先，把三条均线表述出来：
MA5:=MA(CLOSE,5)；
MA10:=MA(CLOSE,10)；
MA30:=MA(CLOSE,30)；
其次，5、10日均线在30日上方，表示5、10日均线的值大于30日均线：
AA:=MA5>MA30 AND MA10>MA30；
然后，用CROSS函数表述5日均线的上穿动作：
BB:=CROSS(MA5,MA10)；
最后，组合以上内容：
AA AND BB；
【死叉】的设计方法同上，只是方向相反。
【三条均线多头排列】：
其定义为：5日均线在10日均线之上，10日均线在30日均线之上，并维持三天的时间。
首先，把三条均线表述出来：
MA5：=MA(CLOSE,5)；
MA10：=MA(CLOSE,10)；
MA30:=MA(CLOSE,30)；
其次，判断各均线的相对位置：
CC:=MA5>MA30 AND MA10>MA30；
然后，统计以上状态维持的天数：
COUNT(CC,3)=3;
【当日成交量放大2倍的金叉】：
MA5：=MA(CLOSE，5)；
MA10：=MA(CLOSE，10)；
AA：=CROSS(MA5，MA10)；
BB：=VOL/REF(VOL，1)>2； {增加一个对成交量的判断}
AA AND BB
2、KDJ指标选股
【K向上交叉D，并且D小于20】：
第一种方法，用公式计算出K、D值，再进行逻辑判断
RSV:=(CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100；
K:=SMA(RSV,M1,1)；
D:=SMA(K,M2,1)；
CROSS(K,D) AND D<20
第二种方法, 直接从已有的KD公式指标中引用K和D的值
AA:=“KD.K”；
BB:=“KD.D”；
CROSS(AA,BB) AND D<20；
【KDJ高位最近连续两次向下交叉确认跌势】：
“高位”的定义模型一般为D值>60。“最近”的定义可以根据习惯来确定，比如示例使用12天的周期。最合适的办法是将以上数值设置为参数灵活使用。
A1:=“KD.K”； {从KD指标中提取出K值}
A2:=“KD.D”； {从KD指标中提取出D值}
A3:=CROSS(A2,A1) AND A2>M；{判断D向下穿过K，并且D值处于高位}
COUNT(A3,N)>=2； {统计以上逻辑表达式成立的次数，至少两次}
3、RSI指标选股
基本买卖原则：
短期RSI值在20以下，由下向上交叉长期RSI值时为买入信号；
短期RSI值在80以上，由上向下交叉长期RSI值时为卖出信号；
短期RSI值由上向下突破50，代表股价已经转弱短期RSI值由下向上突破50，表示强；
条件选股一：RSI上穿20
有两种选择使用，为方便理解，这里选用第二种直接引用技术指标的方式,并使用默认参数：
AA:=“RSI”；
CROSS(AA,20)
条件选股二：相反的选择，沽出时机为RSI向下穿过80：
AA:=“RSI”；
CROSS(80,AA)
4、W&R指标选股
基本买卖原则：
威廉指数计算公式与强弱指数、随机指数一样，计算出的指数值在0至100之间波动。当W％R线达到20时，市场处于超买状况，股价走势随时可能见顶。因此，20的横线一般称为卖出线，投资者在此可以伺机卖出；相反，当W％R线达到80时，市场处于超卖状况，走势可能即将见底，80的横线被称为买入线。
条件选股一：当W％R 线上穿20 时，市场处于超买状况：
A1:=“W&R”；
CROSS(A1,20)
条件选股二：W％R 线下穿80 时，市场处于超卖状况：
A2:=“W&R”；
CROSS(80,A2)
5、MACD指标选股
基本买卖原则：
DIFF上穿DEA，大势属多头市场，可作买；
DIFF下穿DEA，大势属空头市场，可作卖；
以上穿为例：
A1：=“MACD.DIFF”；
A2:=“MACD.DEA”；
CROSS(A1,A2)；
6、BOLL通道选股
基本原则：
当布林通道由宽变窄时，说明股价逐渐向中值回归，股市进入一个整理区间投资者应以观望为主；
当通道由窄变宽时，意味着行情开始发生变化；
如果股价逼近或穿过上限值，表明超买力量增强，股市可能会短期下跌，此时应卖出；反之,当股价逼近或穿过下限值时，表明超卖力量增强,股市可能会反弹向上。
以通道变窄为例：首先要量化“变窄”的具体数值。在不确定取值范围时，可以先编写一个指标公式，绘制出形态，通过观察其结果和特征，选取合理的量化值。
比如，先编写一条指标公式：
A1:=“BOLL.UPPER”; {取BOLL通道的上限值}
A2:=“BOLL.LOWER”; {取BOLL通道的下限值}
A3:=“BOLL.MID”; {取BOLL通道的中间值}
AA:(A1-A2)/A3*100; {计算上下限差值与中间值的比，以此来数量化BOLL通道的宽度}
从绘制出的图形看，当通道变窄时，以上自编的指标AA值大概在10以下，因此我们将BOLL通道变窄这一特性量化为AA小于10。选股公式结果如下：
A1:=“BOLL.UPPER”;
A2:=“BOLL.LOWER”;
A3:=“BOLL.MID”;
AA:=(A1-A2)/A3*100;
AA<10;
7、放量创出新高
这个选股方式有两个条件，一个是放量，即目前成交量比前一天放大，放大多少如果不确定可定义为一个参数N；另一个是创新高，创多少天新高如果不确定，同样可惜定义为一个参数M，如下图：（其中没有简单使用当日成交量，而是用5日均量，这样更科学有效。）
8、单日放量
同样的，放量的概念需要量化为目前成交量比前一天放大多少倍，不确定的情况下可定义为一个参数N倍。另个，为保证放量的有效性，需要保证成交量的绝对值足够大，这里我们使用换手率来表示。在不确定换手率达到多少可认定为量足够大的情况下，设定一个参数M，方便进行调整。代码如下：
9、阶段涨幅选股
【选出N日以来，个股涨幅大于M%的股票】
AA:=REF(CLOSE,N); {取出N日前的收盘价}
CLOSE/AA>1+M/100; {当日收盘价除以N日前收盘价，大于(100+M)/100}
【选出5.19行情中，所有涨幅超过100%的股票】
5.19行情的具体时间段为1999年5月19日到1999年6月29日。
AA:=IF(DATE=990519,CLOSE,0); {提取从5.19以来的所有收盘价，非5.19当天的收盘价全部置为0}
BB:=SUM(AA,0); {汇总以上提取出来的收盘价即为5.19当天的收盘价}
CC:=IF(DATE=990629,CLOSE,0); {提取从6.29以来的所有收盘价，非6.29当天的收盘价全部置为0}
DD:=SUM(CC,0); {汇总以上提取出来的收盘价即为6.29当天的收盘价}
DD/BB>2; {6.29的收盘价为5.19收盘价的两倍}
10、持续放量走高
条件分解后有两个判断标准，一个是放量，一个是价格上涨。需要确认的是持续时间是多长，这个同样可以引入参数，本例中取值为持续三天时间。代码如下：
AA:=MA(VOL,5)>REF(MA(VOL,5),1); {判断当日5日均量大于前一日的5日均量}
BB:=COUNT(AA,3)=3; {统计放量天数是否达到三天}
CC:=CLOSE>REF(CLOSE,1); {判断当日收盘价大于前一日收盘价}
DD:=COUNT(CC,3)=3; {统计价格上涨天数是否达到三天}
BB AND DD; {合并以上两个判断条件}
11、突破长期平台整理
首先，确定何为长期平台整理。这里设定150天为长期，平台范围设定为股份在150日均线上下15%范围内波动。
A1:=MA(CLOSE,150); {算出近150天的均价}
A2:=HHV(HIGH,150); {算出近150天的最高价}
A3:=LLV(LOW,150); {算出近150天的最低价}
A4:=(A2-A1)/A1; {算出最高价相对均价的上涨幅度}
A5:=(A1-A3)/A1; {算出最低价相对均价的下跌幅度}
A:=REF(A4,1)<0.15 AND REF(A5,1)<0.15; {判断上涨幅度和下跌幅度是否小于15%}
为保证突破平台的有效性，需要加上对成交量的判断：
V1:=MA(VOL,5); {算出5日均量}
V2:=VOL/REF(V1,1)>2; {突破当日成交量是均量的两倍}
TP:=(HIGH=A2); {今日股价创新高}
A AND V2 AND TP {综合全部判断条件}
12、逆市走强
所谓逆市，即指逆大盘走势，与大盘背离。
假设为最近三天时间，大盘下跌超过5%，个股不跌反涨。
首先，描述大盘下跌的状态：
AA:=REF(INDEXC,3);
BB:=INDEXC/AA<1-0.05;
其次，描述个股上涨的状态：
CC:=REF(CLOSE,3);
DD:=CLOSE/CC>1;
最后，合并两种状态的判断条件：
BB AND DD;
13、当日放量下跌
“放量”的情况量化为成交量比昨日放大三倍，“下跌”量化为下跌幅度达到5%。
AA:=REF(VOL,1);
BB:=REF(CLOSE,1);
VOL/AA>3 AND CLOSE/BB<0.95;
14、创历史新低
即是，当天的最低价为上市以来所有交易日的最低价：
AA:=LLV(LOW,0);
LOW=AA;
相反，创历史新高如下：
AA:=HHV(HIGH,0);
HIGH=AA;
15、跌破30日生命线
即指，收盘价线从上向下穿过30日均价线。
首先，绘制出收盘价线：
AA:CLOSE;
其次，绘制30日均价线：
BB:=MA(CLOSE,30);
最后，描述收盘价线穿过30日线的情景：
CROSS(BB,AA);
16、涨幅选股
设定条件为：开盘后30分钟涨幅达到5%以上。
动态行情数据用函数DYNAINFO(N)提取，N为14时提取盘中即时涨幅。开盘后30分钟是上午10点，用函数TIME=100000表示。代码如下：
AA:=DYNAINFO(14);
TIME=100000 AND AA>5/100;
17、量比选股
量比是衡量相对成交量的指标。它是指股市开市后平均每分钟的成交量与过去5个交易日平均每分钟成交量之比。可以方便的用于判断是否放量。
简单的量比，如“当前量比>4”，方法同上，使用函数DYNAINFO(N)，将N值换为17即可。
而一些复杂的情景，就需要引入更多的判断条件。比如“昨日涨停，今日开盘后10分钟承接昨天行情继续放量走高，已有一定的升幅和较大的成交量”。
首先，描述昨日涨停的情景：
AA:=REF(CLOSE,2); {提取前天收盘价}
BB:=REF(CLOSE,1); {提取昨天收盘价}
BB/AA>1.0995; {由于存在四舍五入的情况，取值1.0995}
其次，对开盘后10分钟的时间情景进行描述：
CC:=TIME=094000;
量比达到10：
DD:=DYNAINFO(17)>10;
涨幅已达5%：
EE:=DYNAINFO(14)>0.05;
最后，整个预警公式为：
AA:=REF(CLOSE,2);
BB:=REF(CLOSE,1);
CC:=BB/AA>1.0995;
DD:=TIME=094000;
EE:=DYNAINFO(17)>10;
FF:=DYNAINFO(14)>0.05;
CC AND DD AND EE AND FF;
18、尾盘大单拉升
“尾盘”指收盘前十几分钟，本例设定为收盘集合竞价14:55前的十分钟。“大单”指成交量放大，设定为每分钟的均量放大。“拉升”指股价大幅上涨，设定为幅度大于2%。
由于是按分钟进行计算，因此将此公式应用于1分钟K线即可。这样，VOL、CLOSE等函数提取出的数值分别表示一分钟的成交量和一分钟的收盘价。
AA:=TIME>=145500; {收市前5分钟开始进行测算}
BB:=SUM(VOL,235)/235; {将全天235分钟的成交量合计后除以235分钟进行平均}
CC:=SUM(VOL,10)/10; {计算10分钟内的成交均量}
DD:=REF(CLOSE,10); {计算10分钟前的股价}
EE:=CC/BB>3; {10分钟内的均量为全天均量的三倍}
FF:=CLOSE/DD>1.02; {股价比10分钟前上涨2%}
AA AND EE AND FF; {合并以上各条判断条件}
尾盘大单打压的公式编写方式以上类似。
19、盘中巨量向上成交
由于涉及到对单笔成交的计算，因此适合使用分笔成交周期进行预警选股。
“巨量”的概念可以量化为成交量达2000手或成交额达到2000万手，可用函数VOL提取成交量，用函数AMOUNT提取成交额。
“向上”的概念量化为本笔成交价比上笔上涨3%以上。
AA:=REF(CLOSE,10);
CLOSE/AA>1.03 VOL>2000 OR AMOUNT>20000000;
20、空中对敲选股
所谓空中对敲，指在委买和委卖中没有看到有大单挂出，但突然出现一笔大单的成交。设定此成交量要达到委买和委卖中大者的三倍以上，方为大单成交。
同样，因为涉及对单笔成交的计算，此公式适合使用分笔成交周期进行预警选股。
使用函数BIDVOL(N)提取委买量，ASKVOL(N)提取委卖量，BIDPRICE(N)提取委买价， ASKPRICE(N)提取委卖价。
A1:=REF(BIDVOL(1),1); {提取前一笔成交时委买一的量}
A2:=REF(BIDVOL(2),1); {提取前一笔成交时委买二的量}
A3:=REF(BIDVOL(3),1); {提取前一笔成交时委买三的量}
A:=A1+A2+A3; {合计前一笔成交时的委买量}
B1:=REF(ASKVOL(1),1); {提取前一笔成交时委卖一的量}
B2:=REF(ASKVOL(2),1); {提取前一笔成交时委卖二的量}
B3:=REF(ASKVOL(3),1); {提取前一笔成交时委卖三的量}
B:=B1+B2+B3; {合计前一笔成交时的委卖量}
CC:=MAX(A,B); {取委买总量和委卖总量间的大者}
DD:=VOL/CC>3; {判断当笔成交量是否大于委买和委卖间大者的三倍}
E1:=REF(BIDPRICE(3),1); {提取前一笔成交时委买三的价格}
E2:=REF(ASKPRICE(3),1); {提取前一笔成交时委卖三的价格}
EE:=CLOSE>=E2 AND CLOSE<=E1; {确定当笔成交价在委买三到委卖三之间}
DD AND EE; {合并以上判断条件}
21、筹码分布选股
函数COST和WINNER可以通过数学模型尽可能的接近和模拟市场的筹码分布情况。
函数COST(10)的计算结果，表示10%获利盘的价格。即有10%的持仓量在该价格以下，其余90%在该价格以上，为套牢盘。此函数只适用于日线分析周期。
函数WINNER(CLOSE)，表示以当前收市价卖出的获利盘比例，例如返回0.1表示10%获利盘；WINNER(10.5)表示计算10.5元价格的获利盘比例。此函数只适用于日线分析周期。
22、单峰密集形态
所谓单峰密集，指在一个狭窄的价格区间里累积了较多的筹码。当单峰密集出面在价格低位时，股价上涨的可能性较大，反之下跌的可能性较大。
【寻找70%筹码集中的狭窄区域】
首先，找出85%筹码获利的价格位：
A1:=COST(85);
找出15%筹码获利的价格位：
A2:=COST(15);
70%获利区间为：
A3:=A1-A2;
85%和15%获利价格区间的中间价为：
A4:=(A1+A2)/2;
将70%筹码存在的狭窄价格区间定义为中间价的10%，即中间价的上下5%，使用如下判断语句：
A3/A4*100<10;
【低位的单峰密集】
在以上单峰密集逻辑判断上，加入低价位的概念。低位可以设定为价格位于过去250天振幅的下半部位。以下为低价位的判断语句：
B1:=HHV(HIGH,250); {近250天的最高价}
B2:=LLV(LOW,250); {近250天的最低价}
B3:=B1-B2; {近250天的振幅}
(A4-B2)<B3/2; {70%筹码分布的中间价减去近250天的最低价，小于振幅的一半}
【跌破市场成本的反弹】
当一段下降的趋势形成之后，随着成交不断的发生在低位，更低位，从而整个股盘的重心不断的下移，但是并不是所有的重心下移都是一样的。如果从市场的交投情况来看，成交量明显缩小的，换手率偏低的个股，他的重心就下降的很慢，甚至于出现减速，平走的情况。我们可以从几方面来描述这些现象。研究这些形态的原因在于，我们目前已经可以证明，在所有的“V”字反转当中，60%-70%或者更高的比率都会出现上述的情况。(当使用不同的数据测试的时候，有不同的结果)。
首先，在K线图中绘制一条大致能代表市场成本的指标线，然后观察股价每次反弹时与此线的关系。比如股价一般是在偏离此线多少时发生的反弹，再以此为标准编写买卖条件。
市场成本的指标线以50%筹码获利的价格为标准，作为市场的绝对平均成本线：
B:COST(50)；
图形绘制如下：
观察发现，近几次反弹时股价与模拟的市场成本线都是偏离22%，因此可以这样编写超跌反弹公式：
买入条件:
A1:=COST(50)；
CROSS(CLOSE,A1*0.78);
如果是交易公式可以写成IF CROSS(CLOSE,A1*0.78 THEN BUY;
四、基本面选股
基本面选股是指使用各类财务数据进行选股，例如流通盘，市盈率等。主要使用的函数有：
FINANCE (N)，CAPITAL等函数以及设定相关的参数N，根据N值不同可以提取各类财务数据。
【示例】寻找大盘股，即流通盘大于10亿的个股：
CAPITAL>10000000；{CAPITAL的单位是手}
或者，
FINANCE (7)>100000；{该函数的单位是万股，7表示提取流通盘数据}
【示例】市盈率选股，寻找每股市盈率小于30的股票：
SYL:=CLOSE/ FINANCE (33); {33表示提取每股收益}
SYL<30;
【示例】高净资产收益率选股，寻找资产收益率达8%的股票：
FINANCE (29)/ FINANCE (19)>0.08; {税后利润除以净资产}
发布者：股市刺客，转载请注明出处：https://www.95sca.cn/archives/773748
站内所有文章皆来自网络转载或读者投稿，请勿用于商业用途。如有侵权、不妥之处，请联系站长并出示版权证明以便删除。敬请谅解！
